DISPLAY WINDOW message without DSPF

**maran** Mon Dec 12, 2011 8:53 pm

We can display message in window using API QUILNGTX

HDftActGrp(*NO) ActGrp('UTILITY')

DShowText PR
D Text 8192 Const Varying
D MessageId 7 Const
D MessageFile 21 Const

/Free
ShowText('This is an API test. The amount of text that can +
be displayed is nothing short of incredible. The quick +
brown fox jumped over the lazy dog. With an API like this +
available, we shouldn''t need to use the DSPLY opcode any +
longer. It reduces the need for coding DDS WINDOW formats +
and will make life a bed of roses. It even does an +
automatic word wrap. What will they think of next? 123456+
789012345678901234567890123456789012345678901234597890':
'SQL0101':'QSQLMSG');
*InLR=*On;
/End-Free

PShowText B Export
DShowText PI
D Text 8192 Const Varying
D MessageId 7 Const
D MessageFile 21 Const

DErrCode DS
D BytesIn 10I 0 INZ(0)
D BytesOut 10I 0 INZ(0)

DQUILNGTX PR EXTPGM('QUILNGTX')
D MsgText 8192 Const
D MsgLength 10I 0 Const
D MessageId 7 Const
D MessageFile 21 Const
D dsErrCode Like(ErrCode)

/Free
QUILNGTX(Text:%Len(Text):
MessageId:MessageFile:
ErrCode);
/End-Free
PShowText E